Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00045_FileStructTools.ls

Text File | 2004-07-11 | 3.0 KB | 137 lines

--
-- fileStructTools
--

property ancestor
property pathDelim


on new me
  -- set constants:
  if the machineType = 256 then
    set pathDelim = "\"
  else
    set pathDelim = ":"
  end if

  -- initialize the ancestor:
  set ancestor = new (script "StringTools")

  return me
end


-- clear out all of my stuff

on destruct me
  -- destruct my chain
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


-- return the pathDelimiter
on pD me
  return pathDelim
end

-- this will look at a pathname and, based on the pathDelimiter, remove one level from it
-- this defaults to the current "the pathName", or you can pass it a platform specific path
on levelUpPath me, oldPath
  if voidP(oldPath) then
    set oldPath = the pathName
  else
    -- we have a non - void path, make sure they passed in one with some path info in it
    if not(oldPath contains pD(me)) then
      return 0
    end if
  end if

  -- now we want to dissect this puppy
  set the itemDelimiter = pD(me)

  if char (the number of chars of oldPath) of oldPath = pD(me) then
    delete char (the number of chars of oldPath) of oldPath
    delete the last item of oldPath
  else
    delete the last item of oldPath
  end if

  set the itemDelimiter = ","

  -- now we just want to make sure that our return values are consistent
  if oldPath = "" then
    return 0
  else
    return (oldPath & pD(me))
  end if

end

-- given a path, this will return all the items in that path
-- assumes the path is valid
on filesAndFolders me, thePath
  put [] into fileList
  repeat with i = 1 to the maxInteger
    set n = getNthFileNameInFolder(thePath, i)

    if n = EMPTY or n = "" then
      exit repeat
    else
      append(fileList, stringToUpper(me, n))
    end if
  end repeat

  if fileList = [] then
    return 0
  else
    return fileList
  end if

end

-- find out if this path is pointing to a folder
on isFolder me, thePath
  -- we are just going to check if the first entry is available
  set fileCheck = getNthFileNameInFolder(thePath, 1)

  if fileCheck = "" then
    return 0
  else
    return 1
  end if
end

-- this looks into a folder to see if it contains a file
on folderContains me, thePath, theFile
  set theFiles = []
  set theFiles = filesAndFolders(me, thePath)

  -- now we want to see if the folder contains the file
  if theFiles <> 0 then
    if getPos(theFiles, stringToUpper(me, theFile)) <> 0 then
      return 1
    else
      return 0
    end if
  else
    return 0
  end if
end

-- recursive looking for a file in a folder up above thePath
on findFileUpStream me, thePath, theFile
  -- put "looking in: " & thePath & " for: " & theFile
  if folderContains(me, thePath, theFile) then
    return thePath & theFile & pD(me)
  else
    -- now we check to see if we hit the root of the drive and tried to go back one
    set thePath = levelUpPath(me, thePath)
    if thePath = 0 then
      return 0
    else
      -- recurse
      return findFileUpStream(me, thePath, theFile)
    end if
  end if
end